SUMIF函数案例集锦
案例一
语法 =SUMIF(条件区域,指定的条件,需要求和的区域)
案例 条件区域和求和区域相同的情况
公式 =SUMIF(C:C,">3000")
SUMIF的条件表达式有比较运算符的时候，需要用英文输入状态下的双引号括起来，如果是等于则可以直接写等于的数值；如果省略求和区域，会将条件区域作为求和区域。
案例二
语法 =SUMIF(条件区域,指定的条件,需要求和的区域)
案例 求和条件是文本的情况
公式 =SUMIF(B:B,"方方",C:C)（图一）
或 =SUMIF(B:B,E2,C:C) （图二）
图一
图二
1、文本条件,用英文输入状态下双引号括起来或可以直接引用单元格。
案例三
语法 =SUMIF(条件区域,指定的条件,需要求和的区域)
案例 非空条件求和
公式 =SUMIF(B:B,"*",C:C)（图一）
或 =SUMIF(B:B,"<>",C:C)（图二）
图一
图二
1、*为通配符，代表任意字符,等于是不为空的单元格；
2、"<>"表示非空。
案例四
语法 =SUMIF(条件区域,指定的条件,需要求和的区域)
案例 对空白条件求和
公式 =SUMIF(B:B,"",C:C)
1、""代表空白，注意是英文输入状态下的双引号，双引号里面不需要输入任何内容。
案例五
语法 =SUMIF(条件区域,指定的条件,需要求和的区域)
案例 配合通配符使用（模糊求和）
公式 =SUMIF(B:B,"李*",C:C) （图一）
或 =SUMIF(B:B,"???",C:C) （图二）
图一
图二
1、*为通配符，代表任意字符；2、?为通配符，代表任意单个字符；3、与通配符的搭配有多种用法，自行尝试。
案例六
语法 =SUMIF(条件区域,指定的条件,需要求和的区域)
案例 排除某个条件后求和
公式 =SUMIF(B:B,"<>方方",C:C)
1、<>表示不等于；
2、当条件表达式中包含比较运算符的时候需要用英文输入状态下的双引号括起来。
案例七
语法 =SUMIF(条件区域,指定的条件,需要求和的区域)
案例 对低于/高于平均值的单元格求和（公式作为求和条件）
公式 =SUMIF(C:C,"<"&AVERAGE(C:C)) （案例为低于平均值）
1、如果省略求和区域，会将条件区域作为求和区域，案例中条件区域=求和区域，故省略；
2、当使用公式作为求和条件时，如果在求和条件的公式前使用>、<、<>这些比较运算符，运算符需要用英文状态下双引号括起来，同时要使用连接符&，将比较运算符与公式连接起来。
案例八
语法 =SUMIF(条件区域,指定的条件,需要求和的区域)
案例 求和条件为当前日期
公式 =SUMIF(A:A,TODAY(),C:C)
TODAY()函数返回当前日期。
案例九
语法 =SUMIF(条件区域,指定的条件,需要求和的区域)
案例 忽略错误值求和
公式 =SUMIF(C:C,"<9E307")
求和参数省略，以条件区域C:C作为求和区域，9E307完整的表述是9E+307，在EXCEL中属于科学计数法，表示9*10^307，是一个非常接近Excel能够容纳的最大数值的数值，求和条件是<9e307,相当于对所有数值求和。
案例十
语法 =SUMIF(条件区域,指定的条件,需要求和的区域)
案例 与SUM函数结合使用进行多条件求和
公式 =SUM(SUMIF(A:A,{"2月","3月"},C:C))
案例中SUMIF函数的求和条件为数组形式，用SUM函数将SUMIF函数计算的数组结果相加得到最终结果；对于版本较低的EXCEL，数组运算可能需要同时按下Ctrl+Shift+Enter 三个键。
案例十一
语法 =SUMIF(条件区域,指定的条件,需要求和的区域)
案例 隔列求和
公式 =SUMIF($B$2:$G$2,$G$2,B3:G3)
公式中使用了绝对引用和混合引用，以免公式填充时引用单元格位置变化导致错误，是否需要绝对引用或混合引用需要查看实际情况；
案例十二
语法 =SUMIF(条件区域,指定的条件,需要求和的区域)
案例 错列求和
公式 =SUMIF(B2:I13,"方方",C2:I13)
1、注意：条件区域从B列开始框选，而求和区域是从C开始框选，这就是错列求和的原理。
以上案例都是精选挑选，涵盖了工作中碰到到的大部分求和情况，强烈建议收藏，点关注不迷路。
